凹语言中文版重新起航! #

注: 版权 @2025 life 作者。保留所有权利。

引入 "假死门/画布"

函数·主控:
	输出("你好，凹语言中文版！")

	画布对象, _ := 画布·查询画布("canvas")
	画布上下文, _ = 画布对象·获取平面上下文()
完毕

注: 版权 @2025 life 作者。保留所有权利。

引入 "image"
引入 "image/color"
引入 "js/canvas"
引入 "数学/随机数"
引入 "洪荒"

全局:
	宽度 :整型 = 0
	高度 :整型 = 0

	暂停中 :布尔 = 假

	细胞状态甲  :*image·Gray = 空
	细胞状态乙  :*image·Gray = 空
	细胞状态快照 :*image·RGBA = 空

	画布上下文 :canvas·Context2D
完毕

函数·初始化(宽, 高, 随机火种: 整型):
	宽度 = 宽
	高度 = 高

	细胞状态甲 = image·NewGray(宽, 高)
	细胞状态乙 = image·NewGray(宽, 高)
	细胞状态快照 = image·NewRGBA(宽, 高)

	随机数·点火(长整型(随机火种))
	循环 i := 0; i < 宽度*高度; i++:
		如果 (随机数·整数() % 2) != 0:
			细胞状态甲·Pix[i] = color·Gray(1)
		否则:
			细胞状态甲·Pix[i] = color·Gray(0)
		完毕
	完毕
完毕

函数·进化迭代:
	如果 细胞状态快照 == 空:
		返回
	完毕

	如果 !暂停中:
		生命进化()
	完毕

	循环 横 := 0; 横 < 宽度; 横++:
		循环 竖 := 0; 竖 < 高度; 竖++:
			如果 细胞状态甲·Pix[竖*宽度+横] != 0:
				细胞状态快照·SetRGBA(横, 竖, 0xFF0000FF)
			否则:
				细胞状态快照·SetRGBA(横, 竖, 0xFFFFFFFF)
			完毕
		完毕
	完毕

	注: 绘制到 Canvas
	画布上下文·PutImageData(
		洪荒·原生(细胞状态快照·Pix), 0, 0, 0, 0,
		单精(宽度), 单精(高度),
	)
完毕

结构·方向:
	横: 整型
	竖: 整型
完毕

全局·四面八方 = [...]方向{
	{-1, -1}, {0, -1}, {1, -1}, {-1, 0}, {1, 0}, {-1, 1}, {0, 1}, {1, 1},
}

函数·生命进化:
	循环 竖 := 0; 竖 < 高度; 竖++:
		循环 横 := 0; 横 < 宽度; 横++:
			邻居数量 := 0
			循环 位 := 0; 位 < 8; 位++:
				邻横 := (横 + 四面八方[位]·横 + 宽度) % 宽度
				邻竖 := (竖 + 四面八方[位]·竖 + 高度) % 高度
				如果 细胞状态甲·Pix[邻竖*宽度+邻横] != 0:
					邻居数量++
				完毕
			完毕

			如果 细胞状态甲·Pix[竖*宽度+横] != 0:
				找辙 邻居数量:
				有辙 2, 3:
					细胞状态乙·Pix[竖*宽度+横] = color·Gray(1)
				没辙:
					细胞状态乙·Pix[竖*宽度+横] = color·Gray(0)
				完毕
			否则:
				找辙 邻居数量:
				有辙 3:
					细胞状态乙·Pix[竖*宽度+横] = color·Gray(1)
				没辙:
					细胞状态乙·Pix[竖*宽度+横] = color·Gray(0)
				完毕
			完毕
		完毕
	完毕

	注: 交换 细胞状态甲 和 细胞状态乙
	细胞状态甲, 细胞状态乙 = 细胞状态乙, 细胞状态甲
完毕